source/wham/src-M/CMakeLists.txt

   1 #
   2 # CMake project file for WHAM multichain version
   3 #
   4
   5 enable_language (Fortran)
   6
   7 #================================
   8 # Set source file lists
   9 #================================
  10 set(UNRES_WHAM_M_SRC0
  11         wham_multparm.F
  12         bxread.F
  13         xread.F
  14         cxread.F
  15         enecalc1.F
  16         energy_p_new.F
  17         initialize_p.F
  18         molread_zs.F
  19         openunits.F
  20         readrtns.F
  21         arcos.f
  22         cartder.f
  23         cartprint.f
  24         chainbuild.F
  25         geomout.F
  26         gnmr1.f
  27         icant.f
  28         intcor.f
  29         int_from_cart.f
  30         make_ensemble1.F
  31         matmult.f
  32         misc.f
  33         mygetenv.F
  34         parmread.F
  35         permut.F
  36         pinorm.f
  37         printmat.f
  38         rescode.f
  39         setup_var.f
  40         slices.F
  41         store_parm.F
  42         timing.F
  43         wham_calc1.F
  44         readrtns_compar.F
  45         read_dist_constr.F
  46         readpdb.f
  47         fitsq.f
  48         contact.f
  49         elecont.f
  50         contfunc.f
  51         cont_frag.f
  52         conf_compar.F
  53         match_contact.f
  54         angnorm.f
  55         odlodc.f
  56         promienie.f
  57         qwolynes.f
  58         read_ref_str.F
  59         rmscalc.f
  60         secondary.f
  61         proc_cont.f
  62         define_pairs.f
  63         mysort.f
  64 )
  65
  66 set(UNRES_WHAM_M_PP_SRC
  67         bxread.F
  68         chainbuild.F
  69         conf_compar.F
  70         cxread.F
  71         enecalc1.F
  72         energy_p_new.F
  73         geomout.F
  74         initialize_p.F
  75         make_ensemble1.F
  76         molread_zs.F
  77         mygetenv.F
  78         openunits.F
  79         parmread.F
  80         permut.F
  81         read_ref_str.F
  82         read_dist_constr.F
  83         readrtns_compar.F
  84         readrtns.F
  85         slices.F
  86         store_parm.F
  87         timing.F
  88         wham_calc1.F
  89         wham_multparm.F
  90         xread.F
  91         proc_proc.c
  92 )
  93
  94
  95 #================================================
  96 # Set comipiler flags for different sourcefiles
  97 #================================================
  98 if (Fortran_COMPILER_NAME STREQUAL "ifort")
  99   set(FFLAGS0 "-mcmodel=medium -shared-intel  -I. -I${CMAKE_CURRENT_SOURCE_DIR}/include_unres" )
 100 elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
 101   set(FFLAGS0 "-std=legacy -mcmodel=medium -g -I. -I${CMAKE_CURRENT_SOURCE_DIR}/include_unres" )
 102 elseif (Fortran_COMPILER_NAME STREQUAL "pgf90")
 103   set(FFLAGS0 "-mcmodel=medium -Mlarge_arrays -I. -I${CMAKE_CURRENT_SOURCE_DIR}/include_unres" )
 104 else ()
 105   set(FFLAGS0 "-g -mcmodel=medium -I. -I${CMAKE_CURRENT_SOURCE_DIR}/include_unres" )
 106 endif (Fortran_COMPILER_NAME STREQUAL "ifort")
 107
 108
 109 #=========================================
 110 # Add MPI compiler flags
 111 #=========================================
 112 if(UNRES_WITH_MPI)
 113   set(FFLAGS0 "${FFLAGS0} -I${MPI_Fortran_INCLUDE_PATH}")
 114 endif(UNRES_WITH_MPI)
 115
 116 set_property(SOURCE ${UNRES_WHAM_M_SRC0} PROPERTY COMPILE_FLAGS ${FFLAGS0} )
 117
 118 #=========================================
 119 #  Settings for GAB force field
 120 #=========================================
 121 if(UNRES_MD_FF STREQUAL "GAB" )
 122   # set preprocesor flags
 123   set(CPPFLAGS "PROCOR  -DSPLITELE -DCRYST_BOND -DCRYST_THETA -DCRYST_SC  -DSCCORPDB" )
 124
 125 #=========================================
 126 #  Settings for E0LL2Y force field
 127 #=========================================
 128 elseif(UNRES_MD_FF STREQUAL "E0LL2Y")
 129   # set preprocesor flags
 130   set(CPPFLAGS "PROCOR  -DSPLITELE -DSCCORPDB" )
 131 elseif(UNRES_MD_FF STREQUAL "4P")
 132   set(CPPFLAGS "SPLITELE -DLANG0 -DCRYST_BOND -DCRYST_THETA -DCRYST_SC -DSCCORPDB" )
 133 endif(UNRES_MD_FF STREQUAL "GAB")
 134
 135 #=========================================
 136 # Additional flags
 137 #=========================================
 138 set(CPPFLAGS "${CPPFLAGS} -DUNRES -DISNAN")
 139
 140 #=========================================
 141 # System specific flags
 142 #=========================================
 143 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 144   set(CPPFLAGS "${CPPFLAGS} -DLINUX")
 145 endif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 146
 147 #=========================================
 148 # Compiler specific flags
 149 #=========================================
 150
 151 if (Fortran_COMPILER_NAME STREQUAL "ifort")
 152   # Add ifort preprocessor flags
 153   set(CPPFLAGS "${CPPFLAGS} -DPGI")
 154 elseif (Fortran_COMPILER_NAME STREQUAL "f95")
 155   # Add new gfortran flags
 156   set(CPPFLAGS "${CPPFLAGS} -DG77")
 157 elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
 158   # Add old gfortran flags
 159   set(CPPFLAGS "${CPPFLAGS} -DG77")
 160 elseif (Fortran_COMPILER_NAME STREQUAL "pgf90")
 161   set(CPPFLAGS "${CPPFLAGS} -DPGI")
 162   FILE(COPY ${CMAKE_SOURCE_DIR}/source/lib/isnan_pgi.f DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
 163   list(APPEND UNRES_WHAM_M_SRC0 ${CMAKE_CURRENT_BINARY_DIR}/isnan_pgi.f)
 164   set(CMAKE_EXE_LINKER_FLAGS "-Bdynamic")
 165 endif (Fortran_COMPILER_NAME STREQUAL "ifort")
 166
 167 #=========================================
 168 # Add MPI preprocessor flags
 169 #=========================================
 170 set(CPPFLAGS "${CPPFLAGS} -DMPI")
 171
 172 #=========================================
 173 # Add 64-bit specific preprocessor flags
 174 #=========================================
 175 if (architektura STREQUAL "64")
 176   set(CPPFLAGS "${CPPFLAGS} -DAMD64")
 177 endif (architektura STREQUAL "64")
 178
 179 #=========================================
 180 # Apply preprocesor flags to *.F files
 181 #=========================================
 182 set_property(SOURCE ${UNRES_WHAM_M_PP_SRC} PROPERTY COMPILE_DEFINITIONS ${CPPFLAGS} )
 183
 184
 185 #========================================
 186 #  Setting binary name
 187 #========================================
 188 set(UNRES_WHAM_M_BIN "wham-mult_${Fortran_COMPILER_NAME}_MPI_${UNRES_MD_FF}.exe")
 189
 190 #=========================================
 191 # cinfo.f workaround for CMake
 192 #=========================================
 193 # get the current date
 194 TODAY(DATE)
 195 # generate cinfo.f
 196
 197 set(CINFO "${CMAKE_CURRENT_BINARY_DIR}/cinfo.f")
 198 FILE(WRITE ${CINFO}
 199 "C CMake generated file
 200        subroutine cinfo
 201        include 'COMMON.IOUNITS'
 202        write(iout,*)'++++ Compile info ++++'
 203        write(iout,*)'Version ${UNRES_MAJOR}.${UNRES_MINOR} build ${UNRES_PATCH}'
 204 ")
 205
 206 CINFO_FORMAT(${CINFO} "Compiled" "${DATE}" )
 207 CINFO_FORMAT(${CINFO} "Compiled by" "$ENV{USER}@$ENV{HOST}" )
 208 CINFO_FORMAT(${CINFO} "OS name:" "${CMAKE_SYSTEM_NAME}" )
 209 CINFO_FORMAT(${CINFO} "OS release:" "${CMAKE_SYSTEM}" )
 210 CINFO_FORMAT(${CINFO} "Fortran Compiler:" "${CMAKE_Fortran_COMPILER}" )
 211 CINFO_FORMAT(${CINFO} "MD Force field:" "${UNRES_MD_FF}" )
 212 CINFO_FORMAT(${CINFO} "CPPFLAGS =" "${CPPFLAGS}")
 213
 214 FILE(APPEND ${CINFO}
 215 "       write(iout,*)'++++ End of compile info ++++'
 216        return
 217        end ")
 218
 219 # set include paths
 220 set_property(SOURCE ${CMAKE_CURRENT_BINARY_DIR}/cinfo.f PROPERTY COMPILE_FLAGS "${FFLAGS0} -I${CMAKE_CURRENT_SOURCE_DIR}"  )
 221
 222 #=========================================
 223 # Set full unres CSA sources
 224 #=========================================
 225 set(UNRES_WHAM_M_SRCS ${UNRES_WHAM_M_SRC0} ${CMAKE_CURRENT_BINARY_DIR}/cinfo.f proc_proc.c)
 226
 227 #=========================================
 228 # Build the binary
 229 #=========================================
 230 add_executable(UNRES_WHAM_M_BIN ${UNRES_WHAM_M_SRCS} )
 231 set_target_properties(UNRES_WHAM_M_BIN PROPERTIES OUTPUT_NAME ${UNRES_WHAM_M_BIN})
 232 set_property(TARGET UNRES_WHAM_M_BIN PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 233 #add_dependencies (${UNRES_BIN} ${UNRES_XDRFLIB})
 234
 235 #=========================================
 236 # Link libraries
 237 #=========================================
 238 # link MPI library (libmpich.a)
 239 target_link_libraries( UNRES_WHAM_M_BIN ${MPI_Fortran_LIBRARIES} )
 240 # link libxdrf.a
 241 target_link_libraries( UNRES_WHAM_M_BIN xdrf )
 242
 243
 244 #=========================================
 245 # Install Path
 246 #=========================================
 247 install(TARGETS UNRES_WHAM_M_BIN DESTINATION ${CMAKE_INSTALL_PREFIX}/wham)
 248
 249
 250 #=========================================
 251 # TESTS
 252 #=========================================
 253
 254 #  MESSAGE (STATUS "${MPI_Fortran_LIBRARIES}")
 255   if ("${MPI_Fortran_LIBRARIES}"  MATCHES "lam")
 256      MESSAGE (STATUS "LAM MPI library detected")
 257      set (boot_lam "-boot")
 258   else()
 259      set (boot_lam "")
 260   endif()
 261
 262   if (UNRES_SRUN)
 263    set (np "-n")
 264    set (mpiexec "srun")
 265   elseif(UNRES_MPIRUN)
 266    set (np "-np")
 267    set (mpiexec "mpirun")
 268   else()
 269    set (np "-np")
 270    set (mpiexec "mpiexec")
 271   endif()
 272
 273 FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/scripts/wham_mpi_E0LL2Y.sh
 274 "#!/bin/sh
 275 export POT=GB
 276 export PREFIX=$1
 277 #-----------------------------------------------------------------------------
 278 WHAM_BIN=${CMAKE_BINARY_DIR}/bin/${UNRES_WHAM_M_BIN}
 279 #-----------------------------------------------------------------------------
 280 DD=${CMAKE_SOURCE_DIR}/PARAM
 281 export BONDPAR=$DD/bond_AM1.parm
 282 export THETPAR=$DD/theta_abinitio.parm
 283 export ROTPAR=$DD/rotamers_AM1_aura.10022007.parm
 284 export TORPAR=$DD/torsion_631Gdp.parm
 285 export TORDPAR=$DD/torsion_double_631Gdp.parm
 286 export ELEPAR=$DD/electr_631Gdp.parm
 287 export SIDEPAR=$DD/scinter_$POT.parm
 288 export FOURIER=$DD/fourier_opt.parm.1igd_hc_iter3_3
 289 export SCPPAR=$DD/scp.parm
 290 export SCCORPAR=$DD/sccor_am1_pawel.dat
 291 export THETPARPDB=$DD/thetaml.5parm
 292 export ROTPARPDB=$DD/scgauss.parm
 293 export PATTERN=$DD/patterns.cart
 294 export CONTFUNC=GB
 295 export SIDEP=$DD/contact.3.parm
 296 export SCRATCHDIR=.
 297 #-----------------------------------------------------------------------------
 298 echo CTEST_FULL_OUTPUT
 299 ${mpiexec} ${boot_lam} ${np} $2 $WHAM_BIN
 300 ./wham_check.sh $1
 301 ")
 302
 303 #
 304 # File permissions workaround
 305 #
 306 FILE(   COPY ${CMAKE_CURRENT_BINARY_DIR}/scripts/wham_mpi_E0LL2Y.sh
 307         DESTINATION ${CMAKE_CURRENT_BINARY_DIR}
 308         FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
 309 )
 310
 311 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/wham_check.sh
 312         DESTINATION ${CMAKE_CURRENT_BINARY_DIR}
 313         FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
 314 )
 315
 316 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_wham.inp
 317         DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
 318
 319 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_remd_MD000.cx
 320         DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
 321
 322 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y.pdb
 323         DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
 324
 325
 326 if(UNRES_MD_FF STREQUAL "E0LL2Y")
 327     add_test(NAME WHAM_M_remd COMMAND sh ${CMAKE_CURRENT_BINARY_DIR}/wham_mpi_E0LL2Y.sh 1L2Y_wham 2 )
 328 endif(UNRES_MD_FF STREQUAL "E0LL2Y")