source/cluster/wham/src/CMakeLists.txt

   1 #
   2 # CMake project file for cluster analysis from WHAM for single-chain proteins
   3 #
   4
   5 enable_language (Fortran)
   6
   7 #================================
   8 # Set source file lists
   9 #================================
  10 set(UNRES_CLUSTER_WHAM_SRC0
  11         arcos.f
  12         cartprint.f
  13         chainbuild.f
  14         contact.f
  15         convert.f
  16         energy_p_new.F
  17         fitsq.f
  18         geomout.F
  19         gnmr1.f
  20         hc.f
  21         icant.f
  22         initialize_p.F
  23         intcor.f
  24         int_from_cart1.f
  25         main_clust.F
  26         matmult.f
  27         misc.f
  28         noyes.f
  29         parmread.F
  30         pinorm.f
  31         printmat.f
  32         probabl.F
  33         read_coords.F
  34         readpdb.f
  35         readrtns.F
  36         rescode.f
  37         setup_var.f
  38         srtclust.f
  39         ssMD.F
  40         timing.F
  41         track.F
  42         wrtclust.f
  43         work_partition.F
  44 )
  45
  46 set(UNRES_CLUSTER_WHAM_PP_SRC
  47         energy_p_new.F
  48         initialize_p.F
  49         geomout.F
  50         main_clust.F
  51         parmread.F
  52         probabl.F
  53         read_coords.F
  54         readrtns.F
  55         ssMD.F
  56         timing.F
  57         track.F
  58         work_partition.F
  59 )
  60
  61
  62 #================================================
  63 # Set compiler flags for different sourcefiles
  64 #================================================
  65 if (Fortran_COMPILER_NAME STREQUAL "ifort")
  66   set(FFLAGS0 "-mcmodel=medium -shared-intel -ip -w -I. -I${CMAKE_CURRENT_SOURCE_DIR}/include_unres " )
  67 elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
  68   set(FFLAGS0 "-std=legacy -mcmodel=medium -I. -I${CMAKE_CURRENT_SOURCE_DIR}/include_unres " )
  69 else ()
  70   set(FFLAGS0 "-mcmodel=medium -I. -I${CMAKE_CURRENT_SOURCE_DIR}/include_unres " )
  71 endif (Fortran_COMPILER_NAME STREQUAL "ifort")
  72
  73 #=========================================
  74 # Add MPI compiler flags
  75 #=========================================
  76 if(UNRES_WITH_MPI)
  77   set(FFLAGS0 "${FFLAGS0} -I${MPI_Fortran_INCLUDE_PATH}")
  78 endif(UNRES_WITH_MPI)
  79
  80 set_property(SOURCE ${UNRES_CLUSTER_WHAM_SRC0} PROPERTY COMPILE_FLAGS ${FFLAGS0} )
  81
  82 #=========================================
  83 #  Settings for GAB force field
  84 #=========================================
  85 if(UNRES_MD_FF STREQUAL "GAB" )
  86    # set preprocesor flags
  87    set(CPPFLAGS "PROCOR  -DSPLITELE -DCRYST_BOND  -DCRYST_THETA -DCRYST_SC  -DSCCORPDB" )
  88
  89 #=========================================
  90 #  Settings for E0LL2Y force field
  91 #=========================================
  92 elseif(UNRES_MD_FF STREQUAL "E0LL2Y")
  93    # set preprocesor flags
  94    set(CPPFLAGS "PROCOR  -DSPLITELE -DSCCORPDB" )
  95 elseif(UNRES_MD_FF STREQUAL "4P")
  96   set(CPPFLAGS "SPLITELE -DLANG0 -DCRYST_BOND -DCRYST_THETA -DCRYST_SC -DSCCORPDB" )
  97 endif(UNRES_MD_FF STREQUAL "GAB")
  98
  99 #=========================================
 100 # Additional flags
 101 #=========================================
 102 set(CPPFLAGS "${CPPFLAGS} -DUNRES -DISNAN -DCLUST" )
 103
 104 #=========================================
 105 # Compiler specific flags
 106 #=========================================
 107 if (Fortran_COMPILER_NAME STREQUAL "ifort")
 108   # Add ifort preprocessor flags
 109   set(CPPFLAGS "${CPPFLAGS} -DPGI")
 110 elseif (Fortran_COMPILER_NAME STREQUAL "f95")
 111   # Add new gfortran flags
 112   set(CPPFLAGS "${CPPFLAGS} -DG77")
 113 elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
 114   # Add old gfortran flags
 115   set(CPPFLAGS "${CPPFLAGS} -DG77")
 116 endif (Fortran_COMPILER_NAME STREQUAL "ifort")
 117
 118
 119 #=========================================
 120 # System specific flags
 121 #=========================================
 122 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 123   set(CPPFLAGS "${CPPFLAGS} -DLINUX")
 124 endif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 125
 126 #=========================================
 127 # Add MPI preprocessor flags
 128 #=========================================
 129 if (UNRES_WITH_MPI)
 130   set(CPPFLAGS "${CPPFLAGS} -DMP -DMPI")
 131 endif(UNRES_WITH_MPI)
 132
 133
 134 #=========================================
 135 # Apply preprocesor flags to *.F files
 136 #=========================================
 137 set_property(SOURCE ${UNRES_CLUSTER_WHAM_PP_SRC} PROPERTY COMPILE_DEFINITIONS ${CPPFLAGS} )
 138
 139
 140 #========================================
 141 #  Setting binary name
 142 #========================================
 143 set(UNRES_CLUSTER_WHAM_BIN "cluster_wham_${Fortran_COMPILER_NAME}_MPI_${UNRES_MD_FF}.exe")
 144
 145 set_property(SOURCE proc_proc.c PROPERTY COMPILE_DEFINITIONS "LINUX -DPGI" )
 146
 147 #=========================================
 148 # Set full unres CLUSTER sources
 149 #=========================================
 150 set(UNRES_CLUSTER_WHAM_SRCS ${UNRES_CLUSTER_WHAM_SRC0} proc_proc.c)
 151
 152 #=========================================
 153 # Build the binary
 154 #=========================================
 155 add_executable(UNRES_CLUSTER_WHAM_BIN ${UNRES_CLUSTER_WHAM_SRCS} )
 156 set_target_properties(UNRES_CLUSTER_WHAM_BIN PROPERTIES OUTPUT_NAME ${UNRES_CLUSTER_WHAM_BIN})
 157 set_property(TARGET UNRES_CLUSTER_WHAM_BIN PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
 158
 159 #=========================================
 160 # Link libraries
 161 #=========================================
 162 # link MPI libraries
 163 if(UNRES_WITH_MPI)
 164   target_link_libraries( UNRES_CLUSTER_WHAM_BIN ${MPI_Fortran_LIBRARIES} )
 165 endif(UNRES_WITH_MPI)
 166 # link libxdrf.a
 167 target_link_libraries( UNRES_CLUSTER_WHAM_BIN xdrf )
 168
 169 #=========================================
 170 # Install Path
 171 #=========================================
 172 install(TARGETS UNRES_CLUSTER_WHAM_BIN DESTINATION ${CMAKE_INSTALL_PREFIX}/cluster)
 173
 174
 175 #=========================================
 176 # TESTS
 177 #=========================================
 178
 179 #  MESSAGE (STATUS "${MPI_Fortran_LIBRARIES}")
 180   if ("${MPI_Fortran_LIBRARIES}"  MATCHES "lam")
 181      MESSAGE (STATUS "LAM MPI library detected")
 182      set (boot_lam "-boot")
 183   else()
 184      set (boot_lam "")
 185   endif()
 186
 187   if (UNRES_SRUN)
 188    set (np "-n")
 189    set (mpiexec "srun")
 190   elseif(UNRES_MPIRUN)
 191    set (np "-np")
 192    set (mpiexec "mpirun")
 193   else()
 194    set (np "-np")
 195    set (mpiexec "mpiexec")
 196   endif()
 197
 198 FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/scripts/cluster_wham_mpi_E0LL2Y.sh
 199 "#!/bin/sh
 200 export POT=GB
 201 export INPUT=$1
 202 export INTIN=1L2Y_wham
 203 export OUTPUT=1L2Y_clust
 204 export PDB=CART
 205 export COORD=CX
 206 export PRINTCOOR=PRINT_PDB
 207 #-----------------------------------------------------------------------------
 208 CLUSTER_WHAM_BIN=${CMAKE_BINARY_DIR}/bin/${UNRES_CLUSTER_WHAM_BIN}
 209 #-----------------------------------------------------------------------------
 210 DD=${CMAKE_SOURCE_DIR}/PARAM
 211 export BONDPAR=$DD/bond_AM1.parm
 212 export THETPAR=$DD/theta_abinitio.parm
 213 export ROTPAR=$DD/rotamers_AM1_aura.10022007.parm
 214 export TORPAR=$DD/torsion_631Gdp.parm
 215 export TORDPAR=$DD/torsion_double_631Gdp.parm
 216 export ELEPAR=$DD/electr_631Gdp.parm
 217 export SIDEPAR=$DD/scinter_$POT.parm
 218 export FOURIER=$DD/fourier_opt.parm.1igd_hc_iter3_3
 219 export SCPPAR=$DD/scp.parm
 220 export SCCORPAR=$DD/sccor_am1_pawel.dat
 221 export THETPARPDB=$DD/thetaml.5parm
 222 export ROTPARPDB=$DD/scgauss.parm
 223 export PATTERN=$DD/patterns.cart
 224 export CONTFUNC=GB
 225 export SIDEP=$DD/contact.3.parm
 226 export SCRATCHDIR=.
 227 #-----------------------------------------------------------------------------
 228 echo CTEST_FULL_OUTPUT
 229 ${mpiexec} ${boot_lam} ${np} $2 $CLUSTER_WHAM_BIN
 230 ./cluster_wham_check.sh $1
 231 ")
 232
 233 #
 234 # File permissions workaround
 235 #
 236 FILE(   COPY ${CMAKE_CURRENT_BINARY_DIR}/scripts/cluster_wham_mpi_E0LL2Y.sh
 237         DESTINATION ${CMAKE_CURRENT_BINARY_DIR}
 238         FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
 239 )
 240
 241 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/cluster_wham_check.sh
 242         DESTINATION ${CMAKE_CURRENT_BINARY_DIR}
 243         FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
 244 )
 245
 246 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_clust.inp
 247         DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
 248
 249 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_wham.cx
 250         DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
 251
 252 FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y.pdb
 253         DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
 254
 255
 256 if(UNRES_MD_FF STREQUAL "E0LL2Y")
 257     add_test(NAME CLUSTER_WHAM_remd COMMAND sh ${CMAKE_CURRENT_BINARY_DIR}/cluster_wham_mpi_E0LL2Y.sh 1L2Y_clust 2 )
 258 endif(UNRES_MD_FF STREQUAL "E0LL2Y")