# Set of programs to convert UNRES xdrf format (compressed Cartesian coordinates) to PDF
# or raw-Cartesian format (*.x) or to extract backbone angular coordinates (*.ang)
# The pdb files can be constructed from canonical or MREMD trajectories.
#
# The xdrf library is required
#
# Programs
#
# xdrf2pdb   : converts a single cx trajectory file to PDB format
# xdrf2x     : converts a single cx trajectory file to raw-coordinate (x) format
# xdrf2ang   : extracts backbone angles from a cx trajectory file
# xdrf2pdb-m : converts a selected trajectory of a MREMD run dumpend into a cx file to PDB format
#
# xdrf2pdb1  : converts conformation(s) selected from a wham post-processing run into PDB format
# xdrf2x1    : converts conformation(s) selected from a wham post-processing run into raw (x) format.
#
# 9/23/2010 A. Liwo
#
# CMake file by D. Jagieła
# 

set(UNRES_XDRF_XDRF2PDB_SRC
	xdrf2pdb.F
	geomout.F
	misc.f
	rescode.f
	nazwy.f
)

set(UNRES_XDRF_XDRF2PDB-M_SRC
	xdrf2pdb-m.F
	geomout.F
	misc.f
	rescode.f
	nazwy.f
)


set(UNRES_XDRF_XDRF2X_SRC
	xdrf2x.F
)


set(UNRES_XDRF_XDRF2XANG_SRC
	xdrf2ang.f
	misc.f
	rescode.f
	nazwy.f
	intcor.f
	arcos.f
)

set(UNRES_XDRF_PP_SRC
	geomout.F
	xdrf2pdb.F
	xdrf2pdb-m.F
	xdrf2x.F	
)

set(CPPFLAGS "PROCOR -DUNRES -DSPLITELE -DNEWUNRES" )

#=========================================
# System specific flags
#=========================================
if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  set(CPPFLAGS "${CPPFLAGS} -DLINUX")
endif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")

# Apply preprocesor flags to *.F files
set_property(SOURCE ${UNRES_XDRF_PP_SRC} PROPERTY COMPILE_DEFINITIONS ${CPPFLAGS} )

 
#=========================================
# Build the binaries
#=========================================
add_executable(xdrf2pdb   ${UNRES_XDRF_XDRF2PDB_SRC} )
set_property(TARGET xdrf2pdb PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
target_link_libraries( xdrf2pdb xdrf )

add_executable(xdrf2pdb-m ${UNRES_XDRF_XDRF2PDB-M_SRC} )
set_property(TARGET xdrf2pdb-m PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
target_link_libraries( xdrf2pdb-m xdrf )

add_executable(xdrf2x     ${UNRES_XDRF_XDRF2X_SRC} )
set_property(TARGET xdrf2x PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
target_link_libraries( xdrf2x xdrf )

add_executable(xdrf2ang   ${UNRES_XDRF_XDRF2XANG_SRC} )
set_property(TARGET xdrf2ang PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
target_link_libraries( xdrf2ang xdrf )


#=========================================
# Install Path
#=========================================
install(TARGETS xdrf2pdb	DESTINATION ${CMAKE_INSTALL_PREFIX}/xdrfpdb)
install(TARGETS xdrf2pdb-m	DESTINATION ${CMAKE_INSTALL_PREFIX}/xdrfpdb)
install(TARGETS xdrf2x		DESTINATION ${CMAKE_INSTALL_PREFIX}/xdrfpdb)
install(TARGETS xdrf2ang	DESTINATION ${CMAKE_INSTALL_PREFIX}/xdrfpdb)


#=========================================
# TESTS
#=========================================


# Create files needed for tests

file(	COPY ${CMAKE_SOURCE_DIR}/ctest/ala10one.seq
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

file(	COPY ${CMAKE_SOURCE_DIR}/ctest/ala10three.seq 
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

file(	COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Yone.seq
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

file(	COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Ythree.seq
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

file(	COPY ${CMAKE_SOURCE_DIR}/ctest/ala10MD.cx 
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

file(	COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_MREMD_MD000.cx 
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )


# Test xdrf2pdb 
add_test(NAME XDRF2PDB-one   COMMAND xdrf2pdb one ala10one.seq ala10MD.cx )
add_test(NAME XDRF2PDB-three COMMAND xdrf2pdb three ala10three.seq ala10MD.cx )

# Test xdrf2pdb-m
add_test(NAME XDRF2PDB-M-one   COMMAND xdrf2pdb-m one 1L2Yone.seq 1L2Y_MREMD_MD000.cx 32 30 )
add_test(NAME XDRF2PDB-M-three COMMAND xdrf2pdb-m three 1L2Ythree.seq 1L2Y_MREMD_MD000.cx 32 30 )

# Test xdrf2ang
add_test(NAME XDRF2ANG-one   COMMAND xdrf2ang one ala10one.seq ala10MD.cx )
add_test(NAME XDRF2ANG-three COMMAND xdrf2ang three ala10three.seq ala10MD.cx )