c---------------------------------------------------------------------
      subroutine sddir_verlet2
c  Calculating the adjusted velocities for accelerations
      implicit real*8 (a-h,o-z)
      include 'DIMENSIONS'
      include 'COMMON.CONTROL'
      include 'COMMON.VAR'
      include 'COMMON.MD'
#ifndef LANG0
      include 'COMMON.LANGEVIN'
#else
      include 'COMMON.LANGEVIN.lang0'
#endif
      include 'COMMON.CHAIN'
      include 'COMMON.DERIV'
      include 'COMMON.GEO'
      include 'COMMON.LOCAL'
      include 'COMMON.INTERACT'
      include 'COMMON.IOUNITS'
      include 'COMMON.NAMES'
      double precision stochforcvec(MAXRES6),d_as_work1(MAXRES6)
      double precision cos60 /0.5d0/, sin60 /0.86602540378443864676d0/
c Revised 3/31/05 AL: correlation between random contributions to 
c position and velocity increments included.
c The correlation coefficients are calculated at low-friction limit.
c Also, friction forces are now not calculated with new velocities.

c      call friction_force
      call stochastic_force(stochforcvec) 
c
c Compute the acceleration due to friction forces (d_af_work) and stochastic
c forces (d_as_work)
c
      call ginv_mult(stochforcvec, d_as_work1)

c
c Update velocities
c
      do j=1,3
        d_t(j,0)=d_t_new(j,0)+(0.5d0*(d_a(j,0)+d_af_work(j))
     &    +sin60*d_as_work(j)+cos60*d_as_work1(j))*d_time
      enddo
      ind=3
      do i=nnt,nct-1
        do j=1,3
          d_t(j,i)=d_t_new(j,i)+(0.5d0*(d_a(j,i)+d_af_work(ind+j))
     &     +sin60*d_as_work(ind+j)+cos60*d_as_work1(ind+j))*d_time
        enddo
        ind=ind+3
      enddo
      do i=nnt,nct
        if (itype(i).ne.10) then
          inres=i+nres
          do j=1,3
            d_t(j,inres)=d_t_new(j,inres)+(0.5d0*(d_a(j,inres)
     &       +d_af_work(ind+j))+sin60*d_as_work(ind+j)
     &       +cos60*d_as_work1(ind+j))*d_time
          enddo
          ind=ind+3
        endif
      enddo 
      return
      end