#
# CMake project file for WHAM single chain version 
# 

enable_language (Fortran)

#================================
# Set source file lists
#================================

# dummy library for automatic dependency
set(UNRES_WHAM_SRC_DATA
	wham_data.f90 
	w_compar_data.f90
	w_comm_local.f90
)
set(UNRES_WHAM_SRC0 
 ../unres/data/names.f90
 ../unres/data/io_units.f90
 ../unres/data/calc_data.f90
 ../unres/data/compare_data.f90
 ../unres/data/control_data.f90
 ../unres/data/CSA_data.f90
 ../unres/data/energy_data.f90
 ../unres/data/geometry_data.f90
 ../unres/data/MCM_data.f90
 ../unres/data/MD_data.f90
 ../unres/data/minim_data.f90
 ../unres/data/MPI_data.f90
 ../unres/data/comm_local.f90
 ../unres/math.f90
 ../unres/geometry.f90
 ../unres/io_base.f90
 ../unres/energy.f90
 ../unres/control.F90
 ../unres/io_config.f90
 ../unres/regularize.f90
 ../unres/compare.F90
 io_database.f90
 io_wham.f90
 conform_compar.f90
 enecalc.f90
 wham_calc.f90
 work_partition.f90
 wham.f90
)


#================================================
# Set compiler flags for different sourcefiles  
#================================================
if (Fortran_COMPILER_NAME STREQUAL "ifort")
  set (CMAKE_Fortran_FLAGS_RELEASE " ")
  set (CMAKE_Fortran_FLAGS_DEBUG   "-O0 -g ")
  set(FFLAGS0 "-fpp -mcmodel=medium -shared-intel " ) 
elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
  set(FFLAGS0 "-fpp -std=legacy -mcmodel=medium -g ")
elseif (Fortran_COMPILER_NAME STREQUAL "pgf90")
  set(FFLAGS0 "-fpp -mcmodel=medium -Mlarge_arrays ")
else ()
  set(FFLAGS0 "-fpp -g -mcmodel=medium " )
endif (Fortran_COMPILER_NAME STREQUAL "ifort")


#=========================================
# Add MPI compiler flags
#=========================================
if(UNRES_WITH_MPI)
  set(FFLAGS0 "${FFLAGS0} -I${MPI_Fortran_INCLUDE_PATH}")
endif(UNRES_WITH_MPI)

set_property(SOURCE ${UNRES_WHAM_SRC0} PROPERTY COMPILE_FLAGS ${FFLAGS0} )
set_property(SOURCE ${UNRES_WHAM_SRC_DATA} PROPERTY COMPILE_FLAGS ${FFLAGS0} )

#=========================================
#  Settings for GAB force field
#=========================================

if(UNRES_MD_FF STREQUAL "GAB" )
  # set preprocesor flags   
  set(CPPFLAGS "PROCOR -DSPLITELE -DCRYST_BOND -DCRYST_THETA -DCRYST_SC  -DSCCORPDB" )

#=========================================
#  Settings for E0LL2Y force field
#=========================================
elseif(UNRES_MD_FF STREQUAL "E0LL2Y")
  # set preprocesor flags   
  set(CPPFLAGS "PROCOR  -DSPLITELE -DSCCORPDB" )
elseif(UNRES_MD_FF STREQUAL "4P")
  set(CPPFLAGS "SPLITELE -DLANG0 -DCRYST_BOND -DCRYST_THETA -DCRYST_SC -DSCCORPDB" )
endif(UNRES_MD_FF STREQUAL "GAB")


#=========================================
# Additional flags
#=========================================
set(CPPFLAGS "${CPPFLAGS} -DUNRES -DISNAN -DWHAM_RUN ") 


#=========================================
# System specific flags
#=========================================
if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  set(CPPFLAGS "${CPPFLAGS} -DLINUX") 
endif(${CMAKE_SYSTEM_NAME} MATCHES "Linux")

#=========================================
# Compiler specific flags
#=========================================

if (Fortran_COMPILER_NAME STREQUAL "ifort")
  # Add ifort preprocessor flags
  set(CPPFLAGS "${CPPFLAGS} -DPGI") 
elseif (Fortran_COMPILER_NAME STREQUAL "f95")
  # Add new gfortran flags
  set(CPPFLAGS "${CPPFLAGS} -DG77") 
elseif (Fortran_COMPILER_NAME STREQUAL "gfortran")
  # Add old gfortran flags
  set(CPPFLAGS "${CPPFLAGS} -DG77") 
elseif (Fortran_COMPILER_NAME STREQUAL "pgf90")
  set(CPPFLAGS "${CPPFLAGS} -DPGI")
  FILE(COPY ${CMAKE_SOURCE_DIR}/source/lib/isnan_pgi.f DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )
  list(APPEND UNRES_WHAM_SRC0 ${CMAKE_CURRENT_BINARY_DIR}/isnan_pgi.f)
  set(CMAKE_EXE_LINKER_FLAGS "-Bdynamic")
endif (Fortran_COMPILER_NAME STREQUAL "ifort")

#=========================================
# Add MPI preprocessor flags
#=========================================
set(CPPFLAGS "${CPPFLAGS} -DMPI") 

#=========================================
# Add 64-bit specific preprocessor flags
#=========================================
if (architektura STREQUAL "64")
  set(CPPFLAGS "${CPPFLAGS} -DAMD64")
endif (architektura STREQUAL "64")

#=========================================
# Apply preprocesor flags to *.F files
#=========================================
set_property(SOURCE ${UNRES_WHAM_SRC0} PROPERTY COMPILE_DEFINITIONS ${CPPFLAGS} )  
set_property(SOURCE ${UNRES_WHAM_SRC_DATA} PROPERTY COMPILE_DEFINITIONS ${CPPFLAGS} )  

#========================================
#  Setting binary name
#========================================
set(UNRES_WHAM_BIN "wham_${Fortran_COMPILER_NAME}_MPI_${UNRES_MD_FF}.exe")

#=========================================
# cinfo.f workaround for CMake
#=========================================
# get the current date  
TODAY(DATE)
# generate cinfo.f

set(CINFO "${CMAKE_CURRENT_BINARY_DIR}/cinfo.f90")
FILE(WRITE ${CINFO}
"! CMake generated file cinfo.f90
       subroutine cinfo
       use io_units
       write(iout,*)'++++ Compile info ++++'
       write(iout,*)'Version ${UNRES_MAJOR}.${UNRES_MINOR} build ${UNRES_PATCH}'
")

CINFO_FORMAT(${CINFO} "Compiled" "${DATE}" )
CINFO_FORMAT(${CINFO} "Compiled by" "$ENV{USER}@$ENV{HOST}" )
CINFO_FORMAT(${CINFO} "OS name:" "${CMAKE_SYSTEM_NAME}" )
CINFO_FORMAT(${CINFO} "OS release:" "${CMAKE_SYSTEM}" )
CINFO_FORMAT(${CINFO} "Fortran Compiler:" "${CMAKE_Fortran_COMPILER}" )
CINFO_FORMAT(${CINFO} "MD Force field:" "${UNRES_MD_FF}" )
CINFO_FORMAT(${CINFO} "CPPFLAGS =" "${CPPFLAGS}")

FILE(APPEND ${CINFO} 
"       write(iout,*)'++++ End of compile info ++++'  
       return 
       end ")

# set include path
set_property(SOURCE ${CMAKE_CURRENT_BINARY_DIR}/cinfo.f90 PROPERTY COMPILE_FLAGS "${FFLAGS0} -I${CMAKE_CURRENT_SOURCE_DIR}" )
#set_property(SOURCE proc_proc.c PROPERTY COMPILE_FLAGS "-D${CPPFLAGS}")

#=========================================
# Set full unres CSA sources
#=========================================
set(UNRES_WHAM_SRCS ${UNRES_WHAM_SRC0} ${CMAKE_CURRENT_BINARY_DIR}/cinfo.f90 )

#=========================================
# Build the binary
#=========================================
add_executable(UNRES_WHAM_BIN ${UNRES_WHAM_SRCS} )
add_library(wham_data_lib ${UNRES_WHAM_SRC_DATA})
target_link_libraries (UNRES_WHAM_BIN wham_data_lib)
set_target_properties(UNRES_WHAM_BIN PROPERTIES OUTPUT_NAME ${UNRES_WHAM_BIN})
set_property(TARGET UNRES_WHAM_BIN PROPERTY RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin )
#add_dependencies (${UNRES_BIN} ${UNRES_XDRFLIB})

#=========================================
# Link libraries
#=========================================
# link MPI libraries
target_link_libraries( UNRES_WHAM_BIN ${MPI_Fortran_LIBRARIES} )
# link libxdrf.a 
target_link_libraries( UNRES_WHAM_BIN xdrf )

#=========================================
# Install Path
#=========================================
install(TARGETS UNRES_WHAM_BIN DESTINATION ${CMAKE_INSTALL_PREFIX})


#=========================================
# TESTS 
#=========================================

#  MESSAGE (STATUS "${MPI_Fortran_LIBRARIES}")
  if ("${MPI_Fortran_LIBRARIES}"  MATCHES "lam")
     MESSAGE (STATUS "LAM MPI library detected")
     set (boot_lam "-boot")
  else()
     set (boot_lam "")
  endif()

  if (UNRES_SRUN)
   set (np "-n")
   set (mpiexec "srun")
  elseif(UNRES_MPIRUN)
   set (np "-np")
   set (mpiexec "mpirun")
  else()
   set (np "-np")
   set (mpiexec "mpiexec")
  endif()


FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/scripts/wham_mpi_E0LL2Y.sh
"#!/bin/sh
export POT=GB
export PREFIX=$1
#-----------------------------------------------------------------------------
WHAM_BIN=${CMAKE_BINARY_DIR}/bin/${UNRES_WHAM_BIN}
#-----------------------------------------------------------------------------
DD=${CMAKE_SOURCE_DIR}/PARAM
export BONDPAR=$DD/bond_AM1.parm
export THETPAR=$DD/theta_abinitio.parm
export ROTPAR=$DD/rotamers_AM1_aura.10022007.parm
export TORPAR=$DD/torsion_631Gdp.parm
export TORDPAR=$DD/torsion_double_631Gdp.parm
export ELEPAR=$DD/electr_631Gdp.parm
export SIDEPAR=$DD/scinter_$POT.parm
export FOURIER=$DD/fourier_opt.parm.1igd_hc_iter3_3
export SCPPAR=$DD/scp.parm
export SCCORPAR=$DD/sccor_am1_pawel.dat
export THETPARPDB=$DD/thetaml.5parm
export ROTPARPDB=$DD/scgauss.parm
export PATTERN=$DD/patterns.cart
export CONTFUNC=GB
export SIDEP=$DD/contact.3.parm
export SCRATCHDIR=.
#-----------------------------------------------------------------------------
echo CTEST_FULL_OUTPUT
${mpiexec} ${boot_lam} ${np} $2 $WHAM_BIN 
./wham_check.sh $1 
")

#
# File permissions workaround
#
FILE(	COPY ${CMAKE_CURRENT_BINARY_DIR}/scripts/wham_mpi_E0LL2Y.sh 
	DESTINATION ${CMAKE_CURRENT_BINARY_DIR}
	FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
)

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/wham_check.sh
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} 
        FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
)

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_wham.inp
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y_remd_MD000.cx
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )

FILE(COPY ${CMAKE_SOURCE_DIR}/ctest/1L2Y.pdb
        DESTINATION ${CMAKE_CURRENT_BINARY_DIR} )


if(UNRES_MD_FF STREQUAL "E0LL2Y")
    add_test(NAME WHAM_remd COMMAND sh ${CMAKE_CURRENT_BINARY_DIR}/wham_mpi_E0LL2Y.sh 1L2Y_wham 2 )
endif(UNRES_MD_FF STREQUAL "E0LL2Y")